Google Web APIs
Information about the official Google Web APIs (beta 2) - as they call them - can be obtained from the Google website at http://www.google.com/apis/. I don't know why they call them simple APIs while in fact they are APIs made available as a web service. Anyway, at the aforementioned URL, you can see that it takes a mere three steps to start to use the Google APIs:

1. Download the developer's kit
2. Create a Google Account
3. Write your program using your license key

Google Search Key
The second step involves creating a Google Account. This sounds more dangerous than it really is. The use of the Google API is free (at least for now - or let's say: at least at the time of writing), but you need to pass a personal key that will allow you up to 1,000 search queries per day. For non-commercial use only, etc. In order to get this key, you need to register yourself with an existing e-mail address such as ukbug@eBob42.com and a password (although you can quickly forget that password). An e-mail message will be sent to the specified account in order to verify the e-mail address. After you've received the e-mail message and clicked on the link inside, you will receive a second message with your special Google Search Key. In my case, that key is 1WpiIaxr+k+hbyYbRLZOJfg7X9NgI837. The key is included in the source code, so the project executable will work right from the start, although it will only work 1,000 times each day (for all combined users of the executable), so you may want to register yourself and get your own personal Google Search key which entitles you to 1,000 search queries for yourself.

Google Search
Armed with the GoogleSearch.wsdl and the Google Search Key, we can start Delphi 6 (Professional or Enterprise) and build our web service client. Start a new Delphi project and save the (empty) main form in MainForm.pas and the project itself in Google42.dpr (like last time). The first thing we need to do now is to generate a Delphi import unit for the GoogleSearch.wsdl definition, so do File | New - Other, and select the WSDL Importer wizard from the Object Repository. Instead of specifying a URL for the Google Search, you can use the local GoogleSearch.wsdl file - this is especially handy in case you do not have a live internet connection available at all times, because all information is in the local WSDL file.

  type
    DirectoryCategory = class(TRemotable)
    published
      property fullViewableName: String;
      property specialEncoding: String;
    end;

    ResultElement = class(TRemotable)
    published
      property summary: String;
      property URL: String;
      property snippet: String;
      property title: String;
      property cachedSize: String;
      property relatedInformationPresent: Boolean;
      property hostName: String;
      property directoryCategory: DirectoryCategory;
      property directoryTitle: String;
    end;

    ResultElementArray = array of ResultElement;
    DirectoryCategoryArray = array of DirectoryCategory;

    GoogleSearchResult = class(TRemotable)
    published
      property documentFiltering: Boolean;
      property searchComments: String;
      property estimatedTotalResultsCount: Integer;
      property estimateIsExact: Boolean;
      property resultElements: ResultElementArray;
      property searchQuery: String;
      property startIndex: Integer;
      property endIndex: Integer;
      property searchTips: String ;
      property directoryCategories: DirectoryCategoryArray;
      property searchTime: Double;
    end;


    GoogleSearchPort = interface(IInvokable)
    ['{0B396A82-A4DD-69A7-A771-6D80F8831A71}']
      function doGetCachedPage(const key: String; 
        const url: String): TByteDynArray; stdcall;
      function doSpellingSuggestion(const key: String; 
        const phrase: String): String; stdcall;
      function doGoogleSearch(const key: String; const q: String;
        const start: Integer; const maxResults: Integer; const filter: Boolean;
        const restrict: String; const safeSearch: Boolean; const lr: String;
        const ie: String; const oe: String): GoogleSearchResult; stdcall;
    end;

doGoogleSearch
The definition of the doGoogleSearch method of the GoogleSearchPort interface is as follows:

    function doGoogleSearch(const key: String; // your own Google Search Key
      const q: String; // query string
      const start: Integer; // start URLs
      const maxResults: Integer; // maximum results
      const filter: Boolean; // filter alike results?
      const restrict: String; // restrictions
      const safeSearch: Boolean; // adult filter?
      const lr: String; // language?
      const ie: String; // input and output encoding
      const oe: String): GoogleSearchResult; stdcall;

  doGoogleSearch('1WpiIaxr+k+hbyYbRLZOJfg7X9NgI837',Q,0,10,True,'',True,'lang_en','latin1','latin1');

GoogleSearchResult
The GoogleSearchResult has a number of useful properties, such as estimatedTotalResultsCount, searchTime, and resultElements. The last one is an array, of which the elements are of type ResultElement, having a number of interesting subproperties such as title, URL and cachedSize. Using a StringGrid to display the results, the code to call doGoogleSearch and process the results is as follows:

  procedure TForm1.btnSearchClick(Sender: TObject);
  var
    Results: GoogleSearchResult;
    i: Integer;
  begin
    Results := GetGoogleSearchPort.doGoogleSearch('1WpiIaxr+k+hbyYbRLZOJfg7X9NgI837',
      edtQuery.Text, 0, 10, True, '', True, 'lang_en', 'latin1', 'latin1');
    Caption := Format('%d results in %.2n seconds',
      [Results.estimatedTotalResultsCount,Results.searchTime]);
    for i:=Low(Results.resultElements) to High(Results.resultElements) do
    begin
      StringGrid1.Cells[0,Succ(i)] := IntToStr(Succ(i));
      StringGrid1.Cells[1,Succ(i)] := Results.resultElements[i].title;
      StringGrid1.Cells[2,Succ(i)] := Results.resultElements[i].URL;
      StringGrid1.Cells[3,Succ(i)] := Results.resultElements[i].cachedSize
    end
  end;

  procedure TForm1.StringGrid1DblClick(Sender: TObject);
  begin
    with (Sender as TStringGrid) do
      ShellExecute(Handle,'open',PChar(Cells[2,Row]),nil, nil,SW_NORMAL)
  end;

For more recent information on this topic, check out my Delphi 2010 XML, SOAP & Web Services courseware manual.